Office: (Office 365) In einer Zelle Zahlen erkennen und trennen

Guten Tag zusammen
Ich habe folgende Daten in einer Zelle und muss diese in mehrere Spalten aufteilen, insbesondere benötige ich die Zahl, die hinter dem X steht

PKP210SX90AOS08
PKP206X550AOL0890AOL08
PKP210SX4930HS08AOS08

Einzige Konstante ist das X und hinter dem dem X eine Zahl steht, die zwischen 2 und 5 Stellen lang sein kann. Diese rot markierten Zahlen benötige ich. Zahlen die danach kommen, interessieren mich nicht,

Vielleicht kann mir ja jemand helfen.
Das Traurige ist, ich habs schon mal hinbekommen, kann es aber nicht mehr reproduzieren.
Vielen Dank

 

Hallo Evchen,

Zahl ist max. fünfstellig (s. Mappe)

Gruß Sigi

 

Hier etwas kürzer:

 

Oha, herzlichen Dank für die schnellen Antworten. Jetzt müsst ich hald noch herausfinden, wie ich die Zahlenkombination in mehrere Spalten aufteilen kann, also also in diese 3
PKP210SX 1000 AOL90HL

 

Das ist einfach:

 

Hallo PQ-Fan's,

hier mal 1 Lösung mit Power Query.

Gruß von Luschi
aus klein-Paris

 

Hallo Formelfans!
Eine einzige Formelzelle für alle vier Beispiele:

Code:

=LET(
    ax; REGEXEXTRAHIEREN(
        TEXTNACH(A1:A4; "X");
        "\d+"
    );
    bx; TEXTVOR(A1:A4; ax);
    cx; TEXTNACH(A1:A4; ax);
    HSTAPELN(bx; ax; cx)
)

	A	B	C	D
1	PKP210SX90AOS08	PKP210SX	90	AOS08
2	PKP206X550AOL0890AOL08	PKP206X	550	AOL0890AOL08
3	PKP210SX4930HS08AOS08	PKP210SX	4930	HS08AOS08
4	PKP210SX1000AOL90HL	PKP210SX	1000	AOL90HL

Zelle	Formel
B1	=LET( ax;REGEXEXTRAHIEREN(TEXTNACH(A1:A4;"X");"\d+"); bx;TEXTVOR(A1:A4;ax); cx;TEXTNACH(A1:A4;ax); HSTAPELN(bx;ax;cx))

Gruß Ralf

 

Hallo Ralf,

leider kommt Deine Formel in schleudern, sobald es 1 ID-Nr. gibt, die kein Großbuchstabe 'X' enthält. Dann sind die 1. und 3. Spalte mit #NV belegt. Aber sicher kennst Du ein Aspirin-Pille zur Korrektur.

Gruß von Luschi
aus klein-Paris

 

Moin Luschi!
In der Threaderöffnung steht, dass die einzige Konstante das große X ist und die zusammenhängend folgenden Ziffern gesucht werden.

Gruß Ralf

 

Hallo,

=WENNFEHLER(--REGEXEXTRAHIEREN(B4;"X(\d+)";2;0);0)
bzw. als Array
=WENNFEHLER(--REGEXEXTRAHIEREN(B4:B9;"X(\d+)";2;0);0)

 

Hallo,

Mit oder ohne Großbuchstaben X

=LET(ax;--REGEXEXTRAHIEREN(TEXTNACH(B4:B9;"X");"^\d+";;1);bx;TEXTVOR(REGEXERSETZEN(B4:B9;ax;"|");"|");cx;TEXTNACH(REGEXERSETZEN(B4:B9;ax;"|");"|");HSTAPELN(bx;ax;cx))

 

(Office 365) - In einer Zelle Zahlen erkennen und trennen