Office: Mehrere Dokumente gleichzeitig schützen?

Hi Leute!

Ich verwende MS Word 2003 und müsste mehre Dokumente (ca. 180) schützen. Ein einzelnes Dokument kann ich über Extras=>Dokument schützen bearbeiten, aber bei 180 werde ich mit dieser Prozedur alt. Gibt es einen Stapelverarbeitungsbefehl für diese Funktion oder ein kleines Tool?

Für eure Hilfe wäre ich sehr dankbar!

 

Hallo,

vielleicht hilft Dir dieser Beitrag: http://mypage.bluewin.ch/reprobst/WordFAQ/Batch.htm??

 

@Wordmouse: Danke für die rasche Antwort! Ich hab mir den Quellcode durchgelesen.

Was ich jedoch vermisse:
-Passwortvergabe für die zu schützenden Dokumente
-die Funktion "Dokument schützen" aktivieren (und dabei auch angeben können, welche Teile man schützen will: alles, Formular...)

Weiß noch jemand Rat?

Besten Dank im Voraus!

 

Hallo,

das, was Du in diesem Code vermißt, kannst Du einzeln mit dem Makrorekorder aufnehmen und dann im "großen" Code implementieren :lol: ...

 

Wie kann ich von dem momentan verarbeiteten Dokument (ActiveDocument) überprüfen ob es bereits geschützt ist (Extras=>Dokument schützen)?

Die Stapelverarbeitung bricht ab, sobald ein Dokument gefunden wird, das für die Bearbeitung gesperrt ist.

Hier ist mein Prozedurcode für den Dokumentenschutz:

Sub DokumentSchuetzen()
ActiveDocument.Protect Password:="abl", NoReset:=False, Type:= _
wdAllowOnlyReading, UseIRM:=False, EnforceStyleLock:=False
End Sub

Besten Dank im Voraus

 

Hallo,

ein wunderbares Beispiel aus der Hilfe:

Code:

...
If ActiveDocument.ProtectionType = wdNoProtection Then
    ActiveDocument.Protect _
        Type:=wdAllowOnlyFormFields, NoReset:=True
End If
...

 

Hi,

ich mag ja auhc die Seitzen von René - aber manchmal ist der Code doch gerade bezüglich der Fehlrroutine etwas unübersichtlich. Hier mal ein Makro, das den Schutz für alle Worddokumente in einem Verzeichnis und den Untzerverzeichnissen automatisch ändert. Du wirst nach dem Passwort am Anfang gefragt - das Passwort wird für alle Dokumente benutzt. Hier der Code:

Code:

Sub Doku_Schutz()
    Dim anzdatei As Integer
    Dim Pfad
    Dim PW As String
    
Set fs = Application.FileSearch

'hier kann auch ein fester Pfad eingegeben werden
Pfad = InputBox("Geben Sie den Pfad an", "Pfad")

'hier werden nur die insgesamt gefundenen Dateien ausgegeben
If Pfad = "" Then
    MsgBox "Kein Pfad eingegeben!"
    Exit Sub
End If

'Abfrage nach dem Passwort für alle Dateien
PW = InputBox("Bitte das Passwort eingeben:", "Passworteingabe")


If Dir(Pfad, vbDirectory) = "" Then
    MsgBox "Pfad kann nicht gefunden werden!"
    Exit Sub
End If

With fs
    .NewSearch
    .FileType = msoFileTypeWordDocuments   'nur Word-Dokumente!
    .LookIn = Pfad
    .SearchSubFolders = True   'wenn Unterordner auch durchsucht werden sollen
    'folgender Code wird nicht unbedingt gebraucht
    If .Execute = 0 Then
        MsgBox "Es wurden keine Dateien."
        Exit Sub
    End If
    anzdatei = .FoundFiles.Count
End With
 
  
' Verweise in den einzelnen Dateien löschen
On Error Resume Next

For j = 1 To anzdatei
WordBasic.DisableAutoMacros 1
        
        Documents.Open fs.FoundFiles(j)
                
        'Dokuschutz einschalten
        If ActiveDocument.ProtectionType = wdNoProtection Then
            ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True, Password:=PW
        End If
        'Dokument wird gespeichert und geschlossen
        ActiveDocument.Save
        ActiveDocument.Close
Next j
WordBasic.DisableAutoMacros 0

MsgBox "Es wurden " & anzdatei & " Datei(en) neu gespeichert!"

End Sub

Kannst du ja mal mit Deinem Code vergleichen...

 

Hallo zusammen,
ich habe mit vor Jahren die Routine kopiert und (zu) lange benutzt. Jetzt nach dem Umstieg in der Firma auf Office 2019 funktioniert das ganze nicht mehr (Application.FileSearch wird nicht mehr unterstützt...). Leider bin ich ein VBA-Noob und kriege das Makro nicht wieder zum Laufen. Gitb es eine ähnliche Routine oder kennt jemand eine aktuelle alternative/angepasste Implementierung des Makros?
Danke schon mal vorab

 

Hallo ,

statt FileSearch kannst du das FileScripting-Objekt verwenden. Hier ein Beispiel, das ich zwecks Vereinfachung von allen Eventualitäten/Zusatzbedingungen befreit habe:

• Alle Dokumente befinden sich in 1 Ordner, es gibt keine Unterordner
• Im Ordner befinden sich nur Word-Dokumente
• Keins davon verfügt über Automakros (Document_Open, Document_New, AutoOpen, AutoNew)
• Das Passwort ist für alle Dokumente gleich
• Kein Unterdrücken der Bildschirmaktualisierung
• Keine Fehlerbehandlung (muss je nach vorliegenden Umständen evtl. nachgeholt werden)

Teste mal an einigen wenigen Dokumenten:

Code:

Sub Doku_SchutzSetzen()
Dim Pfad As String, PW As String
Dim dok As Document
Dim fso As Object, ordner As Object, datei As Object
  
Pfad = "C:\1temp\sammel\" '**anpassen, dabei letzten Backslash nicht vergessen!
PW = "DeinPW" '**Anpasssen
Set fso = CreateObject("scripting.filesystemObject")
Set ordner = fso.GetFolder(Pfad)
  
    For Each datei In ordner.Files
        Set dok = Documents.Open(Pfad & datei.Name)
        If dok.ProtectionType = wdNoProtection Then
            dok.Protect Type:=wdAllowOnlyFormFields, NoReset:=True, Password:=PW
            dok.Close savechanges:=True
        End If
    Next datei
End Sub

 

Herzlichen Dank für die schnelle Antwort, es funktioniert PERFEKT !
Du kannst nicht ahnen wie dankbar ich bin!
(Die Rekursion für SubFolder werde ich mir am Wochenende mal anschauen und evtl. ausprobieren)