Office: Nach Wörtern in Textmarke suchen und Zeilen formatieren

Hallo!

Es gibt ein Word Dokument mit mehreren Seiten Text. In diesem Dokument steht öfter das Wort "Anteil". In diesem Dokument gibt es auch mehrere Textmarken. In den Textmarken ist jeweils Text von teilweise mehreren Seiten.
Ich hätte gerne ein Makro, dass den Text der Textmarke "TM1" nach dem Wort "Anteil" durchsucht. Wenn das Wort "Anteil" gefunden wird, sollen die Zeile in dem das Wort gefunden wurde und die nachfolgenden zwei Zeilen fett formatiert werden.

Kann mir da jemand helfen?

Vielen Dank!

lg Alex

 

Mir ist die Ziel Vorstellung nicht ganz klar. Wie groß ist denn die Textmarke, dass man darin zum Suchen eines Wortes die Suchfunktion braucht? Wenn Du es gefunden hast, wird es markiert. Was hindert Dich, die drei Zeilen von Hand zu markieren und zu fetten?

 

Danke für deine Antwort.

Die Textmarke ist je nach Vorlage und Eingabe unterschiedlich lang. Im Durchschnitt vermutlich 2 Seiten, es können aber auch 15 sein. Der Begriff kann nur einmal aber auch öfter vorkommen. Insgesamt soll nach 4 Begriffen gesucht werden. Der Einfachheit halber möchte ich das aber vorerst mal mit einem Begriff schaffen.

Vielleicht wird es mit meinem bisherigen Code leichter vorstellbar:

Code:

' ANTEIL: in Textmarke suchen
    Dim suchbereich As Range
    Dim gefunden As Boolean
    Dim textmarke As Range
    
    ' Textmarke "TM1" suchen
    Set textmarke = ActiveDocument.Bookmarks("TM1").Range
    
    ' Suchbereich auf Textmarke setzen
    Set suchbereich = textmarke
    gefunden = True
    
    Do While gefunden
        With suchbereich.Find
            .Text = "ANTEIL:"
            .MatchCase = True  ' Nur exakte Groß-/Kleinschreibung
            .Forward = True    ' Suche vorwärts innerhalb des Suchbereichs
            .Wrap = wdFindStop ' Stoppe die Suche, wenn das Ende des Suchbereichs erreicht ist
            .Execute
        End With
    
        If suchbereich.Find.found Then
            suchbereich.Select
            Selection.Expand unit:=wdLine
            Selection.Font.Bold = True

            Selection.MoveDown unit:=wdLine, Count:=1
            Selection.Expand unit:=wdLine
            Selection.Font.Bold = True

            Selection.MoveDown unit:=wdLine, Count:=1
            Selection.Expand unit:=wdLine
            Selection.Font.Bold = True
        Else
            gefunden = False
        End If
    Loop

Das Probelm bei dem Code ist, dass er das gesamte Dokument durchsucht und nicht nur die Textmarke TM1

lg Alex

 

Hallo Alex,

da musst du eine Notbremse einbauen, die dann greift, sobald eine Fundstelle außerhalb der Textmarke liegt. Ich hab mir bei der Gelegenheit erlaubt, deinen Code ein wenig zu straffen.

Code:

Sub suchAnteil()
Dim fundbereich As Range, bmRange As Range
Dim suchBereichEnde As Long

Set bmRange = ActiveDocument.Bookmarks("TM1").Range
suchBereichEnde = bmRange.End

    With bmRange.Find
        .Text = "ANTEIL:"
        .MatchCase = True
            Do While .Execute
                Set fundbereich = .Parent
                
                'Notbremse:
                If fundbereich.End > suchBereichEnde Then Exit Do
                
                fundbereich.Select
                    With Selection
                        .Expand unit:=wdLine
                        .MoveEnd unit:=wdLine, Count:=2
                        .Font.Bold = True
                    End With
            Loop
    End With
End Sub

 

Lieber Gerhard!

Damit funktioniert's.

Vielen vielen Dank!

lg Alex