Office: (Office 365) Tabelle Filtern mit VBA

Hallo zusammen,

ich bin neu hier und absolutes Greenhorn in Word-VBA. Mit Excel-VBA kenne ich mich leidlich aus, das nützt mir hier wohl leider nichts

Mein Problem:
Ich habe eine 3-spaltige Tabelle mit Tabellenüberschrift (Aufgabe, Zuständig, Vertretung).
Per VBA soll die Spalte 2 auf einen vom Benutzer eingegebenen Begriff durchsucht werden und alle Zeilen ohne diesen Begriff in Spalte 2 sollen gelöscht werden. Dazu habe ich hier im Forum einen Beitrag aus 2016 gefunden, der schon ziemlich gut passt:

Option Compare Text

Sub Tabelle_Filtern()

Dim suchbegriff As String, zeile As Row
Application.UndoRecord.StartCustomRecord ("Tabelle_filtern")
suchbegriff = InputBox("Wonach soll gesucht werden?", "Tabelle filtern")
For Each zeile In Selection.Tables(1).Rows
If Not (zeile.Range.Text Like "*" & suchbegriff & "*") Then zeile.Delete
Next zeile
MsgBox "Filtern nach " & suchbegriff & " beendet. Zum Widerherstellen der Tabelle benutzen Sie die Rückgängig-Funktion."
Application.UndoRecord.EndCustomRecord
End Sub​

Leider wird hier aber immer die gesamte Zeile nach dem Suchbegriff durchsucht. Wie kann ich die Anweisung verändern, dass ausschließlich in Spalte 2 der Tabelle gesucht wird? Taucht der Suchbegriff in Spalte 1 oder 3 auf, nicht aber in Spalte 2, soll die Zeile gelöscht werden.

Und kann man eventuell auch noch einstellen, dass die Überschriftenzeile generell nicht gelöscht wird?

Vielen Dank im Voraus.

Schöne Grüße

luftgetrocknet

 

Hallo luft...
probier mal diese Variante. Sie prüft nur die zweite Spalte, löscht von unten nach oben und hört bei Zeile 2 auf:
Sub Tabelle_Filtern()
Dim tabelle As Table
Dim suchbegriff As String
Dim i As Long, anzZeilen As Long

Set tabelle = Selection.Tables(1)
anzZeilen = tabelle.Rows.Count
suchbegriff = InputBox("Wonach soll gesucht werden?", "Tabelle filtern")
Application.UndoRecord.StartCustomRecord ("Tabelle_filtern")

For i = anzZeilen To 2 Step -1
If Not tabelle.Rows(i).Cells(2).Range.Text Like "*" & suchbegriff & "*" Then tabelle.Rows(i).Delete
Next i

'MsgBox "Filtern nach " & suchbegriff & " beendet. Zum Widerherstellen der Tabelle benutzen Sie die Rückgängig-Funktion."
Application.UndoRecord.EndCustomRecord
End Sub

 

Hallo Gerhard,

das funktioniert genau so, wie ich es beschrieben hatte. Vielen Dank dafür!

Allerdings ist mir inzwischen aufgefallen, dass ich bei der Formulierung einen Denkfehler gemacht hatte . Es müsste nämlich so sein, dass die Zeilen erhalten bleiben, wenn der Suchbegriff entweder in Spalte 2 und/oder Spalte 3 steht. Nur wenn der Suchbegriff in Spalte 1 steht (oder gar nicht in der Zeile), soll die Zeile trotzdem gelöscht werden.

Hast du dafür auch noch eine Idee? Dann wäre es die perfekte Lösung für mich.

Viele Grüße

luftgetrocknet

 

Hallo,

hab das Problem schon selbst gelöst! Vielen Dank für die Starthilfe

Gruß luftgetrocknet