Office: Textboxen im Userform mit Textmarkeninnhalt füllen

Hallo,

ich bearbeite zurzeit ein Word-Dokument mit 60 Textmarken.
Die Textmarken fülle ich mit einem Userform. Die Bezeichnung der Textboxen und Textmarken ist gleich.
Jetzt möchte ich den Spieß umdrehen.
Für Korrekturen in den Textmarken möchte ich mit einen Code das Userfom öffnen und dabei den Inhalt der Textmarken in die Textboxen des Userforms laden.
Ich kann den Inhalt der Textboxen/Textmarken im Userform korrigieren und über den OK Button wieder in das Dokument übernehmen.
Der Versuch, den Code hinter dem OK Button umzudrehen ist leider kläglich gescheitert, jetzt fehlt mir eine Idee.

Wer kann mir helfen?
Vielen Dank.

Frieder

 

Userformname:feldname=textmarke

 

Moin Frieder,
nachdem man nicht weiß, ob Du nur in einem Dokument arbeitest oder immer wieder neue anlegst fallen mir zwei Varianten ein:
Beim Öffnen des Dokuments prüfen, ob bereits Textmarken ausgefüllt sind und falls ja, einfach alle Einträge in die Textboxen übernehmen. Da hilft Dir der Hinweis von G.O. Die falschen Textboxen per Doppelklick leeren und korrigieren. Das geht auch wenn Du die USF aufrufst.

Wenn Du die Einträge manuell holen willst, ist ein zweiter Commanbutton Überarbeiten in der USF der einfachste Weg.

Grüß

 

Hallo zusammen,

Da der Frieder nicht damit rausrückt woran und mit welchem Code er kläglich gescheitert ist, hab ich meine Glaskugel aus ihrem wohlverdienten Weihnachtsurlaub zurückgeholt, und sie sagt:
Der Code von Frieder funktioniert fehlerlos, aber trotzdem werden die Textboxen nicht gefüllt, weil man zwar den Inhalt von Textfeldern an offene Textmarken schreiben kann, aber nichts aus offenen Textmarken lesen kann, da die im Unterschied zu geschlossenen keinen Inhalt haben.

 

Hallo und guten Abend,

danke für die schnellen Rückmeldungen.

1.
Die Vorlage.docm lädt beim öffnen das Userform.
Hier sind Beispieldaten vorgegeben.
Der Anwender gibt die Daten ein und übergibt sie per OK Button and die Vorlage.docm zurück.
(Früher waren das mal 60 Ask-Befehle die per Strg+A & F9 abgefragt wurden.)

2.
Der Code für die Übergabe vom Userform an die Vorlage.docm ist von Hajo_Zi aus einem anderen Thema, siehe unten.
Im Grunde eine If-Then Anweisung und die wollte ich umschreiben, dafür reicht mein VBA Wissen wohl nicht.
Also nicht wenn eine Textmarke mit dem gleichen Namen einer Texbox existiert, dann wird der Text von der Box zur Marke übergeben.
Sondern die Textmarke übergibt den Inhalt an die Box.

Das war eine Idee vom Anwender, um den Inhalt der Textmarken übersichtlich zu korrigieren bzw. zu ändern / anzupassen.
Wenn das passiert ist, dann wieder mit Ok Button die Daten in die Textmarken übergeben.

For Each X In Me.Controls
If TypeOf X Is MSForms.TextBox Then
' TMName = x.Name
' MsgBox X.Name
If ActiveDocument.Bookmarks.Exists(X.Name) Then
Set TMRange = ActiveDocument.Bookmarks(X.Name).Range
TMRange.Text = X.Text
ActiveDocument.Bookmarks.Add Name:=X.Name, Range:=TMRange
End If
End If
Next

 

Hallo Frieder,

wenn ich es richtig verstanden hab, ist das einzige, was du ändern musst, das, was dir in Kurzfassung schon in Beitrag 2 angedeutet wurde:

Code:

Private Sub cmdAusDemDoku_Click()
'vom Dokument in die Textfelder der Userform schreiben
Dim TMRange As Range
Dim X As MSForms.Control

    For Each X In Me.Controls
        If TypeOf X Is MSForms.TextBox Then
            If ActiveDocument.Bookmarks.Exists(X.Name) Then
                Set TMRange = ActiveDocument.Bookmarks(X.Name).Range
                X.Text = TMRange.Text '*****
                'ActiveDocument.Bookmarks.Add Name:=X.Name, Range:=TMRange
            End If
        End If
    Next X
End Sub

Private Sub cmdInsDoku_Click()
'Inhalt der Textfelder der Userform in die Textmarken schreiben
Dim TMRange As Range
Dim X As MSForms.Control
    For Each X In Me.Controls
        If TypeOf X Is MSForms.TextBox Then
            If ActiveDocument.Bookmarks.Exists(X.Name) Then
                Set TMRange = ActiveDocument.Bookmarks(X.Name).Range
                TMRange.Text = X.Text '*****
                ActiveDocument.Bookmarks.Add Name:=X.Name, Range:=TMRange
            End If
        End If
    Next X
Unload Me
End Sub

Wichtig ist, dass es sich bei den Textmarken um geschlossene handelt (also welche, die bei markiertem Bereich entstanden sind). Musterdokument im Anhang (gezippt, da Dokumente mit Makros hier nicht erlaubt sind .

 

Hallo Gerhard,

da sage ich mal DANKE.
Ich habe zu viel gemacht (geändert) und den Wald vor Bäumen nicht gesehen.

Ich habe es gleich eingebaut und es funktioniert einwandfrei.

Vielen Dank
Gruß
Frieder