Office: VBA Makro - Aktuellen Abschnitt drucken

Hallo!

Ich möchte ein VBA-Makro in Word programmieren, das den aktuell ausgewählten Abschnitt (dort wo sich der Cursor befindet) druckt.

Mit der aktuellen Seite funktioniert es schon:
ActiveDocument.PrintOut Range:=wdPrintCurrentPage

Jetzt suche ich etwas im Sinne von:
ActiveDocument.PrintOut Range:=wdPrintCurrentSection

Nur leider funktioniert das so nicht.

Kann mir jemand helfen?

LG

 

Hallo Achdom,

probier mal das:

Code:

Sub druckDenAbschnitt()
Dim abschnNr As Long

abschnNr = Selection.Information(wdActiveEndSectionNumber)
ActiveDocument.PrintOut Background:=False, Range:=wdPrintRangeOfPages, _
Copies:=1, Pages:="s" & abschnNr

End Sub

Achtung, funktioniert nicht mit fortlaufenden Abschnittswechseln. Dafür hab ich noch keine Lösung.

 

Servus Gerhard!

Vielen Dank für Deine rasche Antwort!

Grundsätzlich funktioniert das schon mal.

Es gibt nur noch ein kleines Problem:

Ich arbeite mit "Abschnittsumbruch ungerade Seite". Hier wird die allenfalls bestehende überflüssigen gerade Seite am Beginn des auf den "Abschnittsumbruch ungerade Seite" folgenden Abschnittes einfach ausgeblendet (die in der Statusleiste am unteren Fensterrand angezeigte Seitenzahl wird einfach übersprungen). Beim Drucken des Abschnittes (mit Deinem Makro) wird diese überflüssige Seite jedoch mitgedruckt, sodass der Ausdruck mit einer leeren Seite beginnt, was bei beidseitigem Drucken zu einem Verschiebungsproblem führt.
Selbiges Problem taucht auch beim Drucken über das normale Dialogfeld auf, wenn ich zB nur "s3" (bei zu druckende Seiten) eintippe.

Ein denkbarer Lösungsansatz wäre evtl., dass das Makro überprüft ob der dem aktuell ausgewählten Abschnitt vorhergehende Abschnitt mit einer geraden Seite oder einer ungeraden Seite endet und entsprechend die erste Seite des aktuellen Abschnittes mitdruckt (bei Ende des vorherigen Abschnitts mit gerader Seite) oder die erste Seite des aktuellen Abschnittes nicht mitdruckt (bei Ende des vorherigen Abschnitts mit ungerader Seite). (Achtung wäre geboten beim ersten Abschnitt, da gibt es ja keinen vorhergehenden).

Diese Lösung umzusetzen übersteigt jedoch meine VBA-Fähigkeiten um ein Weites .

Könntest Du mir da vielleicht nochmal helfen? Oder hast Du einen besseren/einfacheren Vorschlag?

LG

 

Hallo Achdom,

ich hab die Sache nachgestellt und bei mir (Word 2019) ist es genau so.

Dann hab ich eine Variante mit viel Selection ausprobiert und bei der scheint es so, dass eine eventuelle Leerseite nie mitgedruckt wird, weil eine leere Seite ja nicht ausgewählt werden kann, so dass man auch keine Unterscheidung treffen muss

Das ist für mich Neuland, entsprechend wenig durchgetestet hab ich das, aber das kannst du ja machen und wieder berichten.

Code:

Sub AbschnittDrucken2()
Dim abschnNr As Long, erste As Long, letzte As Long

'in welchem Abschnitt steht die Schreibmarke?
abschnNr = Selection.Information(wdActiveEndSectionNumber)
MsgBox "Schreibmarke steht im Abschnitt " & abschnNr

'Anfang der erste Seite im Abschnitt ermitteln:
Selection.GoTo what:=wdGoToSection, which:=wdGoToAbsolute, Count:=abschnNr
erste = Selection.Range.Start

'Ende der letzten Seite im Abschnitt ermitteln
Selection.Move unit:=wdSection, Count:=1
letzte = Selection.Range.Start - 1

'Druckbereich auswählen und drucken
ActiveDocument.Range(erste, letzte).Select
ActiveDocument.PrintOut Background:=True, Range:=wdPrintSelection

End Sub
[Code]