Office: (Office 365) Word-Formulr ohne Platzhalter drucken

Hallo,

ich bin neu hier und habe fast keine Programmiererfahrung/Kenntnis.

ich habe ein Word-Formular, dass ich über ein Makro ausdrucken möchte - ohne Platzhalter.
Dabei bekomme ich jedoch immer diese Fehlermeldung: "Laufzeitfehler 91, Objekttyp oder With-Blockvariable nicht festgelegt."
Ich finde den Fehler nicht.

Sub DruckenOhnePlatzhalter()

Dim blnShowHidden As Boolean
Dim blnPrintHidden As Boolean
Dim objCCtl As Word.ContentControl

Set objCCtl = ActiveDocument.ContentControls(1) '''

blnShowHidden = ActiveDocument.ActiveWindow _
.View.ShowHiddenText
blnPrintHidden = Application.Options _
.PrintHiddenText
ActiveDocument.ActiveWindow.View _
.ShowHiddenText = True
Application.Options _
.PrintHiddenText = False

For Each objCCtl In ActiveDocument.ContentControls
With objCCtl
If .Range.Text = .PlaceholderText Then
.Range.Font.Hidden = True
End If
End With
Next objCCtl


Application.Dialogs(wdDialogFilePrint).Show

For Each objCCtl In ActiveDocument.ContentControls
With objCCtl
If .Range.Text = .PlaceholderText Then
.Range.Font.Hidden = False
End If
End With
Next objCCtl

PrtWoPl_End:
ActiveDocument.ActiveWindow.View _
.ShowHiddenText = blnShowHidden

Application.Options _
.PrintHiddenText = blnPrintHidden

Set objCCtl = Nothing
Exit Sub

PrtWoPl_Error:
MsgBox _
Prompt:="Fehler beim Drucken des Formulars" & _
vbCrLf & _
"(" & Err.Number & "): " & Err.Description, _
Buttons:=vbInformation, _
Title:="Formulardruck ohne Platzhaltertext"
Resume PrtWoPl_End

End Sub

Kann mir da bitte jemand weiterhelfen?

Danke und Grüße

 

Hallo,

ich seh auf Anhieb nicht, wo der Fehler entstanden sein könnte. Lass doch dein Makro mal im Einzelschritt (mit F8) durchlaufen und teil die Zeile mit, in der der Fehler auftritt

Übrigens, wenn ein bisschen Schlamperei tolerabel ist, könntest du dir den ganzen Aufwand mit hidden text sparen und im Makro einfach ein Leerzeichen ins Inhaltssteuerelement "eintippen" lassen.

 

Hallo Gerhard,

Danke für Deine Antwort.

Der Fehler tritt in der 1. For - Schleife in dieser Zeile auf:

.Range.Font.Hidden = True…

Danke und Grüße

 

Hallo ifeel,

dann ist es vermutlich so, dass deine Schleife auch ContentControls durchläuft, die keinen Text haben können, wie z.B. Checkboxen.

In diesem Fall hilft es, die Schleife auf bestimmte Typen einzugrenzen. Hier zum Beispiel auf Nur-Text (1) und Rich-Text-Felder (0):

Code:

For Each objCCtl In ActiveDocument.ContentControls
    With objCCtl
        If objCCtl.Type <= 1 Then
            If .Range.Text = .PlaceholderText Then
                .Range.Font.Hidden = True
            End If
        End If
End With
Next objCCtl

Wenn es das nicht ist, braucht es ein kleines Musterdokument zum Testen.

 

Hallo Gerhard,

super, vielen Dank für Deine Hilfe!

Genau das war das Problem, hatte ich gar nicht auf dem Schirm.

Freundliche Grüß und schönen Sonntag