Office: (Office 2003) Zahlen im Text addieren

Hallo.

Ich suche nach einer Möglichkeit in einem solchen Text:

Iif([DezimalZeit102]>1;[Zeit102]) & Iif([DezimalZeit131]>1;" --|-- " &[Zeit131]) & Iif([DezimalZeit160]>1;" --|-- " &[Zeit160]) & Iif([DezimalZeit189]>1;" --|-- " &[Zeit189])& Iif([DezimalZeit218]>1;" --|-- " &[Zeit218]) & Iif([DezimalZeit247]>1;" --|-- " &[Zeit247]) & Iif([DezimalZeit276]>1;" --|-- " &[Zeit276]) &Iif([DezimalZeit305]>1;[Zeit305]) & Iif([DezimalZeit334]>1;" --|-- " &[Zeit334]) & Iif([DezimalZeit363]>1;" --|-- " &[Zeit363]) & Iif([DezimalZeit392]>1;" --|-- " &[Zeit392])& Iif([DezimalZeit421]>1;" --|-- " &[Zeit421]) & Iif([DezimalZeit450]>1;" --|-- " &[Zeit450])

alle enthaltenen Zahlen mit 1 zu addieren. Aus 102 sollte 103 werden, aus 131 die 132 usw.

Gibt es diese Möglichkeit? Ansonsten müsste ich das händisch machen und zwar 30mal mit unterschiedlichn Zahlen.

Ich freue mich über Tipps.

Vielen Dank.

Grüße
Bimbi

 

Hallo,

wenn du folgende beide VBA-Funktionen in ein allgemeines VBA-Codemodul kopierst, kannst du deinen Ausdrucksstring entsprechend nach deinen Vorstellungen modifizieren.
Ich habe dir eine Excel-Datei angefügt, die diese Funktionen bereits enthält.
Im Arbeitsblatt "Tabelle1" habe ich in die Zelle A6 deinen Beispielausdruck eingefügt und in Zelle A8 folgende Formel:
=ErhöheVariablenNr(A6)
sodass dann in dieser Zelle A8 der gewünschte modifizierte Formelausdruck erscheint.

Voraussetzungen, dass die Modifizierung funktioniert:
1) Die zu ändernden Variablen müssen alle in "[" und "]" eingeschlossen sein, zB. "[DezimalZeit132]".
2) Der Inhalt dieser eckigen Klammern wird von meiner 2. Funktion "ScanBez_Add(...)" analysiert und,
2a) falls er lauter erlaubte Zeichen enthält, wird der Nummernteil des Variablenbezeichners um 1 erhöht.
2b) falls unerlaubte Zeichen enthalten sind, werden die eckigen Klammern samt Inhalt unverändert übernommen.

Code:

Option Explicit

Function ErhöheVariablenNr(Formel As String) As String
  Dim S() As String
  Dim I As Long, Ps As Long
  
  ErhöheVariablenNr = Formel
  On Error GoTo Err_Erhöhe
  
  S$ = Split(Formel, "]")
  For I = LBound(S) To UBound(S) - 1
    Ps = InStrRev(S(I), "[")
    S(I) = Left$(S(I), Ps - 1) & "[" & ScanBez_Add(Mid$(S(I), Ps + 1), 1)
  Next I
  ErhöheVariablenNr = Join(S$, "]")
  
Err_Erhöhe:
End Function

Function ScanBez_Add(Bez As String, Erhöh As Integer) As String
  Dim Ps As Long, Ch As String
  Dim PsTxt As Long
  Dim SyntaxOk As Boolean
  Const TxtMatch As String = "[A-Za-zÄÖÜßäöü]"
  Const NrMatch As String = "#"
  
  SyntaxOk = True: PsTxt = 0
  For Ps = Len(Bez) To 1 Step -1
    Ch = Mid(Bez, Ps, 1)
    If PsTxt Then
TesteNochmals:
      If Not Ch Like TxtMatch Then SyntaxOk = False: Exit For
    Else
      If Not Ch Like NrMatch Then PsTxt = Ps: GoTo TesteNochmals
    End If
  Next Ps
  
  If SyntaxOk Then
    Ch = "": If PsTxt < Len(Bez) Then Ch = Mid(Bez, PsTxt + 1) + Erhöh
    ScanBez_Add = Left(Bez, PsTxt) & Ch
  Else
    ScanBez_Add = Bez
  End If
  
End Function