Office: (Office 365) Zelle mit Text und Zahlen aufteilen

Hallo,
gibt es eine Möglichkeit eine Zelle (A2 und A3) aufzuteilen?
Die Zelle enthält Text und Zahlen und sollten wie in der Mustertabelle ab Spalte B bis Spalte G aufgeteilt werden.
Ist das überhaupt möglich?
Schon mal Danke im Voraus

 

Hi,

mit VBA schon - z.B. so:

Code:

Sub Trennen()
    Dim intSpalte As Integer
    Dim lngZeile As Long
    Dim intZaehler As Integer
    intSpalte = 2
    For lngZeile = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        Cells(lngZeile, intSpalte) = Cells(lngZeile, intSpalte) & Mid(Cells(lngZeile, 1), 1, 1)
        For intZaehler = 2 To Len(Cells(lngZeile, 1))
            If (IsNumeric(Cells(lngZeile, intSpalte)) And IsNumeric(Mid(Cells(lngZeile, 1), intZaehler, 1))) Or _
                (Not IsNumeric(Cells(lngZeile, intSpalte)) And Not IsNumeric(Mid(Cells(lngZeile, 1), intZaehler, 1))) Then
                Cells(lngZeile, intSpalte) = Cells(lngZeile, intSpalte) & Mid(Cells(lngZeile, 1), intZaehler, 1)
            Else
                Cells(lngZeile, intSpalte) = RTrim(LTrim(Cells(lngZeile, intSpalte)))
                intSpalte = intSpalte + 1
                Cells(lngZeile, intSpalte) = Cells(lngZeile, intSpalte) & Mid(Cells(lngZeile, 1), intZaehler, 1)
            End If
        Next intZaehler
        intSpalte = 2
    Next lngZeile
End Sub

---

 

Moin!
=LET(a;A2;
n;SEQUENZ(LÄNGE(a));
x;(ISTZAHL(--TEIL(a;n;1))+ISTZAHL(--TEIL(a;n+1;1))=1)*(n+1);
TEXTTEILEN(TEXTKETTE(TEIL(a;n;1)&WENN(ISTZAHL(XVERGLEICH(n+1;FILTER(x;x);0;2));";";""));";"))
Habe ich von hier:
Ziffern und Nichtziffern trennen

Gruß Ralf

 

Hallo Karin,
danke für den VBA-Code. Hab es mit dem Code versucht und funktioniert auch. Doch bei mir ist der Rechner mit ca. 5000 Datensätze ewig gelaufen.

Hallo Ralf,
mit Deinem Befehl hat es super funktioniert und die ca. 5000 Datensätze waren in kürzester Zeit durch. Auf diese Weise habe ich eine Menge Zeit gespart.

Dennoch vielen Dank für Eure Mithilfe und wünsche Euch ein schönes Weihnachtsfest.

Gruß Martin

 

Hi Martin,

nicht alle Excel-Versionen kennen die gepostete Formel - so z.B. ist sie in Excel2016 ungültig. Gewiss dauert es mit VBA länger, weil der String Zeichen für Zeichen durchlaufen wird - aber zumindest ist er in Excel2016 (und allen anderen Versionen) gültig...

---

 

Beverly hat sich einfach die Zeit gespart, die Stringbereiche vorher in Variant-Arrays zu packen. Damit wäre es genauso schnell geworden.

Danke RPP63 für die Verlinkung!

 

Wie würde denn der VBA-Code mit dem Variant-Arrays aussehen?
Da ich mich mit VBA nicht so auskenne, könntet Ihr mir da mit dem VBA-Code nochmal helfen?

 

Warum willst Du VBA-Code, wenn Du doch eine funktionierende schnelle Formel hast?

 

Es ist aus reiner Interesse wie so ein Code dann aussieht und vielleicht lerne ich VBA etwas mehr kennen.

 

Hi,

es gibt sicher verschiedene Möglichkeiten, hier eine davon, wenn (wie in deiner Mappe) feststeht, in wieviele Spalten aufgeteitlt werden soll:

Code:

Sub Trennen()
    Dim intSpalte As Integer
    Dim lngZeile As Long
    Dim intZaehler As Integer
    Dim lngZaehler As Long
    Dim arrWerte()
    For lngZeile = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        ReDim Preserve arrWerte(0 To 5, 0 To lngZaehler)
        arrWerte(intSpalte, lngZaehler) = Mid(Cells(lngZeile, 1), 1, 1)
        For intZaehler = 2 To Len(Cells(lngZeile, 1))
            If (IsNumeric(arrWerte(intSpalte, lngZaehler)) And IsNumeric(Mid(Cells(lngZeile, 1), intZaehler, 1))) Or _
                (Not IsNumeric(arrWerte(intSpalte, lngZaehler)) And Not IsNumeric(Mid(Cells(lngZeile, 1), intZaehler, 1))) Then
                arrWerte(intSpalte, lngZaehler) = arrWerte(intSpalte, lngZaehler) & Mid(Cells(lngZeile, 1), intZaehler, 1)
            Else
                arrWerte(intSpalte, lngZaehler) = RTrim(LTrim(arrWerte(intSpalte, lngZaehler)))
                intSpalte = intSpalte + 1
                If intSpalte < 6 Then arrWerte(intSpalte, lngZaehler) = Mid(Cells(lngZeile, 1), intZaehler, 1)
            End If
        Next intZaehler
        lngZaehler = lngZaehler + 1
        intSpalte = 0
    Next lngZeile
    Range("B2").Resize(lngZaehler, 6) = Application.Transpose(arrWerte())
End Sub

---